【9RIA—ladeng6666】—【Box2D系列教程 34】用PhysicsEditor快速创建自定义Box2D刚体(一)

9RIA-ladeng6666

转载：9RIA游戏开发者社区（天地会）
作者：ladeng6666（拉登大叔）
作者博客：http://www.ladeng6666.com/blog/


【Box2D系列教程-导航帖】—拉登大叔出品（总贴）



PhysicsEditor，相信很多人都已经很熟悉了，通过它的可视化编辑界面，点一点，拉一拉就可以轻松创建任意的多边形刚体模型，并将这个模型数据导出成我们所需的格式，例如AS3类。PhysicsEditor支持Box2D、Cocos2d、Nape等多种2D物理引擎。闲话少说，我们马上开始学习PhysicsEditor。

PS：如果你喜欢学习英文资料，可以参考这里。


在学习PhysicsEditor之前，先讲一下它是uhe跟Flash一起工作的。学习新事物就要和我们熟悉的东西联系到一起，这样才能理解的更快，不是吗？！大约有下面几个步骤：
    1. 在PhysicsEditor中创建好刚体模型后(怎么创建，稍后再讲)，导出成一个PhysicsData.as类。这个类中有一个createBody方法，用来创建刚体，以及保存了刚体的顶点数据。
    2. 把在PhysicsEditor中用来创建刚体模型的图像导入到Flash中，稍后作为刚体的userData使用。当然，如果不需要userData，可以省略这一步。
    3. 创建文档类，键入代码，创建一个基本的Box2D世界。
    4. 在文档类中，创建一个PhysicsData实例对象，用下面的代码创建刚体。然后正常的更新Box2D世界就可以了。
以拉登大叔的头像为例，实现的效果如下，点击舞台创建头像。



具体的用PhysicsEditor创建刚体模型和导入PhysicsData类的方法，我们下一节继续介绍。上面示例的完整代码和注释如下：

[Actionscript3] 纯文本查看 复制代码

package  
{
        import Box2D.Collision.b2WorldManifold;
        import Box2D.Common.Math.b2Vec2;
        import Box2D.Dynamics.b2Body;
        import Box2D.Dynamics.b2World;
        import Box2D.Dynamics.Contacts.b2Contact;
        import flash.display.Bitmap;
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.MouseEvent;

        /**
         * ...
         * @author ladeng6666
         */
        public class Main extends Sprite 
        {
                private var world:b2World;
                private var phyicsData:PhysicsData;

                public function Main() 
                {
                        createWorld();//创建世界

                        phyicsData = new PhysicsData();
                        //添加事件侦听器
                        addEventListener(Event.ENTER_FRAME, loop);
                        stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);

                }
                //创建Box2D世界
                private function createWorld():void 
                {
                        //创建Box2D世界
                        world = world = new b2World(new b2Vec2(0, 10), true);
                        //添加调试视图
                        addChild(LDEasyBox2D.createDebug(world));
                        LDEasyBox2D.stage = stage;
                        LDEasyBox2D.createWrapWall(world, this);

                }

                private function onMouseDown(me:MouseEvent):void 
                {
                        //用拉登大叔的头像创建userData,并添加到舞台上
                        var userData:Bitmap = new Bitmap(new ladeng6666(0, 0));
                        addChild(userData);
                        //用physicsData实例的createBody方法创建刚体，参数的重点是第一个
                        //它是在PhysicsEditor中添加的图像的名称，不要Flash库里的图像名称混为一谈
                        //现在不明白也没关系，下一节我们会仔细学习
                        var body:b2Body = phyicsData.createBody("ladeng6666", world, b2Body.b2_dynamicBody, userData);
                        //设置刚体的坐标
                        var position:b2Vec2 = new b2Vec2(mouseX / phyicsData.ptm_ratio, mouseY / phyicsData.ptm_ratio);
                        position.Subtract(body.GetLocalCenter());
                        body.SetPosition(position);
                }

                private function loop(e:Event):void 
                {
                        var body:b2Body = world.GetBodyList();
                        //遍历所有的刚体，更新它们的userData的坐标个角度
                        for (; body; body = body.GetNext()) {
                                if (body.GetUserData() != null) {
                                        body.GetUserData().x = body.GetPosition().x * phyicsData.ptm_ratio;
                                        body.GetUserData().y = body.GetPosition().y * phyicsData.ptm_ratio;
                                        body.GetUserData().rotation = body.GetAngle() *180/Math.PI;                                        
                                }
                        }
                        LDEasyBox2D.updateWorld(world);
                }

        }

}

下载：
OK 2012-12-09 用PhysicsEditor快速创建自定义Box2D刚体.rar (348.35 KB, 下载次数: 0)

2018-2-6 12:42 上传

点击文件名下载附件