【9RIA—ladeng6666】—【Box2D系列教程 21】Box2D如何创建固定动态刚体
转载：9RIA游戏开发者社区（天地会）作者：ladeng6666（拉登大叔）
作者博客：http://www.ladeng6666.com/blog/
【Box2D系列教程-导航帖】—拉登大叔出品（总贴）
从开始学习Box2D到现在，我们认识了很多的刚体。如圆形刚体，圆角刚体，矩形刚体，多边形刚体等等。但是这些刚体不外乎两种：静态刚体和动态刚体。静态刚体不进行物理模拟，在创建位置静止不动。动态刚体受重力作用，模拟物理运动自然下落。
但是有时候我们并不希望刚体一个劲的往下掉，要不就是跟石头似的，一动不动。比如像wake up the box4游戏里的这个传送带效果(下面的游戏截图是第26关，所以要像看到效果，你得费点力气，玩吧！)。
幸运的是，上面的效果可以通过我们学到的"马达关节"b2Revolute来实现(如果你还不知道什么是马达关节，赶紧去学习一下吧)。
我们知道马达关节连接了两个刚体，实际上，只要固定其中一个刚体，另一个刚体也就固定了(前提是另一个刚体的中心在anchor节点位置)。我把"马达关节"里的风扇的底座bodyB设置设置为静态刚体后，效果如下，试着拖动刚体看看效果。
attach://847.swf
主要的代码如下：
//创建bodyB刚体,设置isStatic参数为true，标示为静态刚体
bodyB = LDEasyBox2D.createBox(world, posB.x, posB.y, 200, 50, true);
但是wake up the box4游戏里没有我们所谓的底座啊，怎么办？对，用"空刚体"！
b2World有一个GetGroundBody()方法，可以返回一个没有质量、没有形状、不进行碰撞检测的刚体，它是一个只有坐标的刚体，所以我叫他"空刚体"。这样就可以把底座去掉了。
像游戏里一样，我创建了三个圆形刚体，并给左下角的刚体添加了torque扭力。点击鼠标可以创建一个小的圆形刚体，按住control键，点击鼠标可以创建一个矩形刚体，点击"reset"清除创建的刚体。
attach://845.swf
完整的代码和注释如下：
package
{
import Box2D.Common.Math.b2Vec2;
import Box2D.Dynamics.b2Body;
import Box2D.Dynamics.b2World;
import Box2D.Dynamics.Joints.b2RevoluteJointDef;
import com.bit101.components.PushButton;
import flash.display.Sprite;
import flash.display.Stage;
import flash.events.Event;
import flash.events.KeyboardEvent;
import flash.events.MouseEvent;
import flash.ui.Keyboard;
/**
* ...
* @author ladeng6666
*/
public class FixDynamicBody extends Sprite
{
private var world:b2World;
private var allThings:Array = new Array();
private var keyDown:uint;
public function FixDynamicBody()
{
//创建world世界
world = LDEasyBox2D.createWorld();
//添加调试图
addChild(LDEasyBox2D.createDebug(world));
LDEasyBox2D.stage = this;
//设置包围的刚体墙
LDEasyBox2D.createWrapWall(world,stage);
//创建3个旋转的，但位置固定的旋转刚体
createMotorCirle(340, 200);
createMotorCirle(220, 230);
createMotorCirle(100, 260,500);//给最左下角的刚体添加一个扭力
//侦听各种事件
addEventListener(Event.ENTER_FRAME, loop);
stage.addEventListener(MouseEvent.MOUSE_DOWN, onStageMouseDown);
stage.addEventListener(KeyboardEvent.KEY_DOWN, keyEventHandler);
stage.addEventListener(KeyboardEvent.KEY_UP, keyEventHandler);
//添加一个按钮
setUI();
}
//创建马达关节，使刚体可以旋转
private function createMotorCirle(posx:Number, posy:Number, torque:Number = 0):void {
//创建刚体
var body:b2Body = LDEasyBox2D.createCircle(world, posx, posy, 50);
//创建马达关节需求
var revoluteJointDef:b2RevoluteJointDef = new b2RevoluteJointDef();
//初始化马达关节，设置节点为刚体的圆心，这只bA为空刚体
revoluteJointDef.Initialize(world.GetGroundBody(), body, new b2Vec2(posx / 30, posy / 30));
//如果扭力不为0，则添加扭力
if (torque != 0) {
revoluteJointDef.enableMotor = true;
revoluteJointDef.motorSpeed = Math.PI*2;
revoluteJointDef.maxMotorTorque = torque;
}
//创建马达关节
world.CreateJoint(revoluteJointDef);
}
//键盘事件处理器
private function keyEventHandler(e:KeyboardEvent):void
{
//侦听control键是否按下
if (e.type == KeyboardEvent.KEY_DOWN) {
keyDown = e.keyCode;
}else if (e.type == KeyboardEvent.KEY_UP) {
keyDown = 0;
}
}
//鼠标事件处理器
private function onStageMouseDown(e:MouseEvent):void
{
if (e.target is Stage) {
var body:b2Body;
//如果control键按下，则创建矩形刚体，否则创建圆形刚体
if (keyDown == Keyboard.CONTROL) {
body = LDEasyBox2D.createBox(world, mouseX, mouseY, 200, 10);
}else {
body = LDEasyBox2D.createCircle(world, mouseX, mouseY, 17);
}
//记录所创建的刚体，待会在点击"reset"按钮时，全部清除
allThings.push(body);
}
}
private function loop(e:Event):void
{
//更新世界
LDEasyBox2D.updateWorld(world);
}
private function setUI():void {
var button:PushButton = new PushButton(this, 400, 20, "Reset", onButtonClick);
function onButtonClick(me:MouseEvent) {
//点击按钮后，清除allThings里的所有刚体
for each(var item:* in allThings) {
world.DestroyBody(item);
}
}
}
}
}
代码中用到了我写的静态类LDEasyBox2D，可以有效的简化代码。
下载：
页:
[1]