【9RIA—ladeng6666】—【Box2D系列教程 36】Box2D刚体缩放
转载：9RIA游戏开发者社区（天地会）
作者：ladeng6666（拉登大叔）
作者博客：http://www.ladeng6666.com/blog/
【Box2D系列教程-导航帖】—拉登大叔出品（总贴）
刚刚提缩放，无非就是设置一下width、height或scaleX、scaleY属性嘛，这么简单的东西也要写个教程？很遗憾的告诉你，Box2D刚体不像Flash里的显示对象，没有width、height或scaleX、scaleY这样的属性，那么怎么办呢？继续看教程！
好吧，即使不一样，这么简单的东西能做出什么样的效果？能做游戏？没错，不怕做不到，就怕想不到。Shrink it就是用刚体缩放制作的一个游戏(如下图)，点击刚体进行缩放，让上面的多边形碰撞星星，这也是今天我们要模仿的效果。
不是显示对象，就无法使用width、height或scaleX、scaleY来调整刚体的大小了。不过我们还是有办法的！
b2Body类没有直接影响刚体尺寸的属性或方法，而是要通过b2Shape类的一些方法来实现，所以首先要用b2Body.GetFixtureList().GetShape()获取刚体的图形，然后根据图形的类型进行不同的设置。
//获取鼠标点击刚体的图形数据
var pressedShape = pressedBody.GetFixtureList().GetShape();
我们知道b2Shape的子类有两种，一个是b2CircleShape类，这个图形的尺寸调整起来比较简单，直接调用b2CircleShape.setRadius()就可以重新设置新的半径。参数可以设置为b2CircleShape.getRadius()*scale来进行比例缩放，代码如下：
//通过SetRadius()方法，将圆形的半径缩小为0.9倍
pressedShape.SetRadius(pressedShape.GetRadius()*.9);
另一个是b2PolygonShape类，因为多边形的顶点数量和位置不同，形成的图形也不同，所以没有类似于SetRadius()的SetWidth()或SetHeight()方法。实际上，我们可以把多边形分解成多个顶点，多边形等比例缩放时，顶点到中心点的距离也是等比例缩放的(如下图所示)，所以我们只需要用顶点向量的Multiply()方法乘以指定的缩放比例即可。
//遍历图形的所有顶点，将顶点到中心点的距离缩小为0.9倍
for each( var vec:b2Vec2 in pressedShape.GetVertices()) {
vec.Multiply(0.9);
}
下面的示例中，我模拟了Shrink it游戏的第一关，点击动态刚体进行缩放，点击Restart按钮重置刚体。
attach://816.swf
完整的源代码和注释如下：
package
{
import Box2D.Collision.Shapes.b2CircleShape;
import Box2D.Collision.Shapes.b2PolygonShape;
import Box2D.Collision.Shapes.b2Shape;
import Box2D.Common.Math.b2Vec2;
import Box2D.Dynamics.b2Body;
import Box2D.Dynamics.b2World;
import com.bit101.components.PushButton;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
/**
* ...
* @author ladeng6666
*/
public class Main extends Sprite
{
private var world:b2World;
public function Main()
{
//创建世界
createWorld();
//侦听事件
setupEvent();
//创建刚体
createBody();
//添加按钮
setUI();
}
private function createWorld():void
{
//添加世界
world = LDEasyBox2D.createWorld();
//添加调试试图
addChild(LDEasyBox2D.createDebug(world));
LDEasyBox2D.stage = this;
}
private function createBody():void
{
//添加包围的墙体
LDEasyBox2D.createWrapWall(world, this);
//创建圆形刚体
LDEasyBox2D.createCircle(world, 300, 50, 30);
//创建8边形
LDEasyBox2D.createRegular(world, 255, 50, 30, 8);
//创建动态刚体
LDEasyBox2D.createBox(world, 270, 170, 288, 30);
//创建3个静态的刚体
LDEasyBox2D.createBox(world, 140, 200, 100, 30, true);
LDEasyBox2D.createBox(world, 400, 200, 100, 30, true);
LDEasyBox2D.createBox(world, 265, 300, 100, 30, true);
}
private function clearBodies():void {
//清除所有的刚体
var body:b2Body;
for (body = world.GetBodyList(); body; body = body.GetNext()) {
world.DestroyBody(body);
}
}
private function setupEvent():void
{
stage.addEventListener(Event.ENTER_FRAME, loop);
stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseHandler);
}
private function mouseHandler(e:MouseEvent):void
{
var pressedBody:b2Body = LDEasyBox2D.getBodyAtMouse(world);
if (pressedBody == null || pressedBody.GetType() == b2Body.b2_staticBody) return;
//获取鼠标点击刚体的图形数据
var pressedShape = pressedBody.GetFixtureList().GetShape();
if (pressedBody.GetFixtureList().GetShape() is b2CircleShape) {
//通过SetRadius()方法，将圆形的半径缩小为0.9倍
pressedShape.SetRadius(pressedShape.GetRadius()*.9);
}else {
//遍历图形的所有顶点，将顶点到中心点的距离缩小为0.9倍
for each( var vec:b2Vec2 in pressedShape.GetVertices()) {
vec.Multiply(0.9);
}
}
//缩放完之后，唤醒刚体
pressedBody.SetAwake(true);
}
private function loop(e:Event):void
{
LDEasyBox2D.updateWorld(world);
}
private function setUI():void
{
var btn:PushButton = new PushButton(this, 270, 15, "ReStart", function():void {
clearBodies();
createBody();
});
}
}
}
下载：
页:
[1]